Notion 常用公式片段教程

可直接复制的日期、成员、文本清洗、状态标签等常用公式片段。

本页收录日常最常用的小公式。适合已经知道问题场景，想直接复制公式时使用。

使用时先确认自己的属性名，再复制对应片段。

场景	用到的主要函数
安全显示日期	`empty()`、`formatDate()`
安全显示成员	`map()`、`name()`、`join()`
文本清洗	`trim()`、`replaceAll()`
状态标签	`ifs()`、`style()`

安全显示日期

if(empty(prop("日期")), "未设置", formatDate(prop("日期"), "YYYY-MM-DD"))

安全显示成员

if(empty(prop("成员")), "未分配", prop("成员").map(current.name()).join("、"))

安全显示关联页面标题

if(empty(prop("项目")), "无项目", prop("项目").map(current.prop("项目名称")).join("、"))

已完成任务比例

lets(
  任务, prop("任务"),
  总数, 任务.length(),
  完成数, 任务.filter(current.prop("状态") == "已完成").length(),
  if(总数 == 0, 0, 完成数 / 总数)
)

文本清洗

trim(replaceAll(prop("文本"), "\\s+", " "))

中文顿号连接列表

prop("标签").join("、")

从文本中提取数字

match(prop("文本"), "\\d+")

判断是否本周内截止

lets(
  剩余天数, dateBetween(prop("截止日期"), today(), "days"),
  剩余天数 >= 0 and 剩余天数 <= 7
)

生成序号文本

优先用最新参考函数：

format(prop("序号")).padStart(3, "0")

兼容写法：

substring("000" + format(prop("序号")), length("000" + format(prop("序号"))) - 3)

多条件状态标签

ifs(
  prop("状态") == "已完成", style("已完成", "green", "b"),
  empty(prop("截止日期")), style("未排期", "gray"),
  prop("截止日期") < today(), style("逾期", "red", "b"),
  prop("截止日期") == today(), style("今日", "yellow", "b"),
  style("进行中", "blue")
)

常用片段

安全显示日期

安全显示成员

安全显示关联页面标题

已完成任务比例

文本清洗

中文顿号连接列表

从文本中提取数字

判断是否本周内截止

生成序号文本

多条件状态标签

目录